// Exemple d'appel avec un champ jauge qui existe (si il n'existe pas le programme copie quand même)
CopyFileEX("D:\Temp\cosmologie_03.m4v", "E:\cosmologie_03.m4v", MaJauge..NomComplet)

Procedure CopyFileEX(ExistingFileName est une chaîne, NewFileName est une chaîne, pJaugeName est une chaîne = "")

//https://forum.pcsoft.fr/fr-FR/pcsoft.fr.windev/224118-jauge-progression-cecopiefichier-230476/read.awp
ResAPI est un boolean
DiskFree, hndDll est un entier
lpData est un entier sur 4 octets
DllName, TargetDisk est une chaîne
JaugeName est une chaîne ASCIIZ sur 512 = pJaugeName

DllName = "Kernel32.dll"


// Vérifier si le fichier source existe
IF NOT fFichierExiste(ExistingFileName) THEN
Erreur(ChaîneConstruit("Le fichier : %1, n'existe pas !",ExistingFileName))
RETOUR
END

// et qu'il contient quelque chose.
IF fTaille(ExistingFileName) = 0 THEN
Info(ChaîneConstruit("Le fichier : %1 est vide !", ExistingFileName))
RETOUR
END

// Vérifier si le disque cible existe
TargetDisk = fExtraitChemin(NewFileName, fDisque)

IF NOT fDisquePrêt(TargetDisk) THEN
Erreur(ChaîneConstruit("Disque : %1, invalide !", TargetDisk))
RETOUR
END

// Calcule l'espace libre sur le disque cible pour le comparer à la taille du fichier à copier
DiskFree = fDisqueInfo(TargetDisk, fdEspaceLibre)
IF fFichierExiste(NewFileName) THEN DiskFree += fTaille(ExistingFileName) // on va effacer la cible cela va liberer de la place

//Vérifier si la place libre est suffisante
IF fTaille(ExistingFileName) > DiskFree THEN
Erreur(ChaîneConstruit("Place insuffisante sur le lecteur : %1 !", TargetDisk))
RETOUR
END

// Si le fichier existe déjà on demande si on doit le remplacer par le nouveau fichier
IF fFichierExiste(NewFileName) THEN
IF OuiNon(Non, ChaîneConstruit("Le fichier : %1 existe déjà. Voulez-vous le remplacer par : %2", NewFileName, ExistingFileName)) = Oui THEN
IF NOT fSupprime(NewFileName) THEN
Erreur(ChaîneConstruit("Impossible de supprimer le fichier : %1", NewFileName))
RETOUR
END
ELSE
RETOUR
END
END

// Chargement de la dll
hndDll = ChargeDLL(DllName)
IF hndDll = 0 THEN
Erreur(ChaîneConstruit("Chargement de %1 impossible !", DllName))
RETOUR
END

// Pour la jauge
IF ChampExiste(JaugeName) _AND_ {JaugeName, indChamp}..Type = typJauge THEN
{JaugeName, indChamp}..BorneMax = fTaille(ExistingFileName)
{JaugeName, indChamp}..Visible = True
lpData = &JaugeName
ELSE
lpData = Null
END

// Go
// see : https://docs.microsoft.com/fr-fr/windows/desktop/api/winbase/nf-winbase-copyfileexa
Sablier(True)
ResAPI = API(DllName, "CopyFileExA", &ExistingFileName, &NewFileName, &progressRoutine, &JaugeName, False, 0)

IF ChampExiste(JaugeName) _AND_ {JaugeName, indChamp}..Type = typJauge THEN {JaugeName}..Visible = False
Sablier(False)
IF NOT ResAPI THEN Erreur("Echec de la copie...") ELSE Info("Fichier copié.")

DéchargeDLL(hndDll)

// see : https://docs.microsoft.com/fr-fr/windows/desktop/api/winbase/nc-winbase-lpprogress_routine
Procedure progressRoutine(TotalFileSize est un entier sur 8 octets, TotalBytesTransferred est un entier sur 8 octets,...
StreamSize est un entier sur 8 octets, StreamBytesTransferred est un entier sur 8 octets,...
StreamNumber est un entier sur 4 octets, CallbackReason est un entier sur 4 octets,...
hSourceFile est un entier sur 4 octets, hDestinationFile est un entier sur 4 octets,...
lpData est un entier sur 4 octets)

JaugeName est une chaîne = ""

IF lpData <> Null THEN
WHEN EXCEPTION IN
JaugeName = ChaîneRécupère(lpData, crAdresseASCIIZ)
IF ChampExiste(JaugeName) _AND_ {JaugeName, indChamp}..Type = typJauge THEN
{JaugeName, indChamp}..Valeur = TotalBytesTransferred
END
DO

END
END

IF ToucheEnfoncée(teEchap, False) THEN
IF OuiNon(Non, "Arrêt de la copie ?") = Oui THEN RENVOYER PROGRESS_CANCEL ELSE RENVOYER PROGRESS_CONTINUE
END

RENVOYER PROGRESS_CONTINUE