Procedure RemplirTable(sIDCpte est une chaîne = "61")

LOCAL
sListeMois, sLibellé, sNoMois sont des chaînes
sEx1, sEx2, sMois sont des chaînes
i est un entier

ST_MaStruct est une structure
LibMois est une chaîne
Ex1 est un réel
Ex2 est un réel
Evol est un réel
FIN

// [< Description tableau de structure >]
TabMvts est un tableau de 12 ST_MaStruct

// [< Liste des mois]
sListeMois = "01/02/03/04/05/06/07/08/09/10/11/12"
sLibellé = oFormat:LibelléDuCompte(sIDCpte)
LIB_Fenetre = ChaîneConstruit("Compte : %1 - %2", sIDCpte, sLibellé)

MaFenêtre..AffichageActif = Faux

sEx1 = SAI_Exerc
sEx2 = Val(sEx1)-1
TABLE_Mouvts.COL_EX1..Libellé = sEx1
TABLE_Mouvts.COL_EX2..Libellé = sEx2

// [< Constrution du tableau >]
Sablier()

i = 1
POUR TOUTE CHAINE sNoMois DE sListeMois SEPAREE PAR "/"

// [< Exercice 1 >]
sMois = ChaîneConstruit("%1%2", sEx1, sNoMois)
TabMvts[i]:LibMois = DateVersMoisEnLettre(sMois+"01")
TabMvts[i]:Ex1 = TotalDuMois(sMois, sIDCpte)

// [< Exercice 2 >]
sMois = ChaîneConstruit("%1%2", sEx2, sNoMois)
TabMvts[i]:Ex2 = TotalDuMois(sMois, sIDCpte)

// [< Evolution >]
TabMvts[i]:Evol = ( TabMvts[i]:Ex1 - TabMvts[i]:Ex2 )

// [< Mois suivant >]
i++

FIN

TableSupprimeTout(TABLE_Mouvts)

// [< Optimiser chargement >]
TABLE_Mouvts..AffichageActif = Faux
TABLE_Mouvts..TotauxActif = Faux

// [< Affichage des données >]
POUR i = 1 A 12
TableAjouteLigne(TABLE_Mouvts, TabMvts[i]:LibMois, TabMvts[i]:Ex1, TabMvts[i]:Ex2, TabMvts[i]:Evol)
FIN

// [< Réactiver calcul automatique >]
TABLE_Mouvts[ligneTotal]..Hauteur = 20
TABLE_Mouvts..AffichageActif = Vrai
TABLE_Mouvts..TotauxActif = Vrai

// [< Couleur Total >}
COL_Evolution[ligneTotal]..Couleur = (COL_Evolution[ligneTotal] > 0 ? CouleurDéfaut SINON RougeClair)
COL_ValBef3[ligneTotal]..Couleur = (COL_Evolution[ligneTotal] > 0 ? CouleurDéfaut SINON RougeClair)

// [< Libérer mémoire >]
Dimension(TabMvts, 0)

Sablier(Faux)
EcranPremier(TABLE_Mouvts)

MaFenêtre..AffichageActif = Vrai