xl est un objet automation dynamique
xl = ObjetActif("Excel.Application")
SI xl = Null ALORS
Info("Aucun Document Excel détecté")
FIN
SI xl <> Null ALORS

sName est une chaîne UNICODE

POUR i=1 _À_ xl>>Workbooks>>Count()
sName =xl>>Workbooks(i)>>Name
sChemin est une chaîne = xl>>Workbooks(i)>>Path
TableAjouteLigne(TABLE_Excel_Ouvert,sName,sChemin+"\"+sName)
FIN
TABLE_Excel_Ouvert..Visible = Vrai
TableSelectMoins(TABLE_Excel_Ouvert)

FIN

API_FindWindowEx est une Description d'API
AVEC API_FindWindowEx
..NomDLL = "USER32"
..NomFonction = "FindWindowExA" // utilise des chaînes ANSI
..TypeRetour = apiEntierSystème // HWND
..Paramètre[1]..Type = apiEntierSystème // HWND hWndParent
..Paramètre[2]..Type = apiEntierSystème // HWND hWndChildAfter
..Paramètre[3]..Type = apiEntierSystème // LPCSTR lpszClass
..Paramètre[4]..Type = apiEntierSystème // LPCSTR lpszWindow
FIN

API_AccessibleObjectFromWindow est une Description d'API
AVEC API_AccessibleObjectFromWindow
..NomDLL = "OLEACC"
..NomFonction = "AccessibleObjectFromWindow"
..TypeRetour = apiEntier_4 // HRESULT
..Paramètre[1]..Type = apiEntierSystème // HWND hwnd
..Paramètre[2]..Type = apiEntier_4 // DWORD dwId
..Paramètre[3]..Type = apiEntierSystème // REFIID riid (pointeur sur IID, GUID)
..Paramètre[4]..Type = apiEntierSystème // void **ppvObject
FIN

GUID est une structure
Data1 est un entier sur 4 octets // DWORD
Data2 est un entier sur 2 octets // WORD
Data3 est un entier sur 2 octets // WORD
Data4 est un Buffer sur 8 octets // BYTE[8]
FIN

// Pseudo-constantes
C_XLMAIN est une chaîne ANSI = "XLMAIN"
C_XLDESK est une chaîne ANSI = "XLDESK"
C_EXCEL7 est une chaîne ANSI = "EXCEL7"
S_OK est un entier sur 4 octets = 0
C_IID_IDispatch est une chaîne UNICODE = "{00020400-0000-0000-C000-000000000046}" // LPOLESTR
C_OBJID_NATIVEOM est un entier sur 4 octets = 0xFFFFFFF0 // DWORD

// Identifiant de l'interface IDispatch
IID_IDispatch est un GUID
nResultIID est un entier = API("OLE32","IIDFromString",&C_IID_IDispatch,&IID_IDispatch)

Procedure ListerApplicationsExcel(tabAppExcel_inout est un tableau d'objet automation dynamique) : entier

nCompteur est un entier
hWndMain,hWndDesk,hWndExcel est un entier système

// rechercher la fenêtre de 1er niveau de classe XLMAIN
hWndMain = API_FindWindowEx(0,0,&C_XLMAIN,0)

TANTQUE hWndMain <> 0
BOUCLE (1) // pseudo-bloc de code
// rechercher la fenêtre de classe XLDESK
hWndDesk = API_FindWindowEx(hWndMain,0,&C_XLDESK,0)

SI hWndDesk = 0 ALORS SORTIR // sortir du pseudo-bloc de code

// rechercher la fenêtre de classe EXCEL7
hWndExcel = API_FindWindowEx(hWndDesk,0,&C_EXCEL7,0)

SI hWndExcel = 0 ALORS SORTIR // sortir du pseudo-bloc de code

// récupérer une référence à l'objet OLE Excel.Application
nResult est un entier sur 4 octets
nAdresse est un entier système

nResult = API_AccessibleObjectFromWindow(hWndExcel,C_OBJID_NATIVEOM,&IID_IDispatch,&nAdresse)

SI nResult <> S_OK ALORS SORTIR

IOLE_ExcelApplication est un COMObjet
IOLE_ExcelApplication..Adresse = nAdresse

// >> BUG pour "transformer un objet COM en objet OLE Automation
autAppExcel est un objet automation dynamique
autAppExcel = IOLE_ExcelApplication

TableauAjoute(tabAppExcel_inout,autAppExcel)

nCompteur++

FIN // fin pseudo-bloc de code

// boucler sur la prochaine fenêtre de 1er niveau de classe XLMAIN
hWndMain = API_FindWindowEx(0,hWndMain,&C_XLMAIN,0)
FIN

RENVOYER nCompteur

tabAppExcel est un tableau d'objets automation dynamique
nCompteurApp est un entier

nCompteurApp = ListerApplicationsExcel(tabAppExcel)