WindowsFound est un booléen
WinPID est un entier système
ExcelFileName, CompleteExcelFileName, ListeDesFenetres, sLigne est une chaîne
xl est un objet automation dynamique

ExcelFileName = "tests.xlsx"
CompleteExcelFileName = ComplèteRep(fRepExe()) + ExcelFileName
IF NOT fFichierExiste(ExcelFileName) THEN
Erreur("Fichier Excel inconnu !")
RETOUR
END

xl = allouer un objet automation "Excel.Application"
IF xl = Null THEN
Erreur("Erreur 'Excel.application' n'est pas installé sur ce poste !")
RETOUR
END
xl>>Visible = True
xl>>WorkBooks>>Open(CompleteExcelFileName)
Multitâche(0)
ListeDesFenetres = EnumWindows()
IF ListeDesFenetres = "" THEN
Erreur("Impossible de lister les fenêtres !")
xl>>ActiveWorkbook>>Close()
xl>>Quit()
RETOUR
END

WindowsFound = False
FOR ALL STRING sLigne OF ListeDesFenetres SEPARATED by CRLF
IF ChaîneOccurrence(sLigne, ExcelFileName) > 0 THEN WindowsFound = True; SORTIR
END

IF NOT WindowsFound THEN
Erreur("Fenêtre non trouvée !")
xl>>ActiveWorkbook>>Close()
xl>>Quit()
RETOUR
END
WinPID = Val(ExtraitChaîne(sLigne, 1), 16)

IF EnModeTest() THEN Trace(ObjetActif("Excel.Application") <> Null ? "Actif" ELSE "Inactif")
API("User32.dll", "ShowWindow", WinPID, 3)
IF EnModeTest() THEN Trace(ObjetActif("Excel.Application") <> Null ? "Actif" ELSE "Inactif")

// test d'écriture...
xl>>Range("A6")>>Value = "1"
xl>>Range("A7")>>Value = "2"
xl>>Range("A8")>>Value = "3"

FUNCTION EnumWindows(pHndParent est un entier système = -1):chaîne
resDLL est un booléen
MyHandle, nbChar, Pid est un entier système
Patern, Liste, Temp, WindowsListe est une chaîne

WindowsListe = ""

Patern = Répète("Z", 8) + Caract(0x0d) // 9 octets
Liste = Répète(Patern, 1000) //(9 * 1000)+1 pour le 0x00 terminal soit len=9001 pour lpClassName et lpLibellé
lpClassName, lpLibellé est une chaîne ASCIIZ sur 9001

IF pHndParent = -1 THEN
// Premier passage on traite le cas des parents : «EnumWindows»
//see : http://msdn.microsoft.com/en-us/library/windows/desktop/ms633497%28v=vs.85%29.aspx
resDLL = API(user32_dll, "EnumWindows", &EnumWindowsFunction, &Liste)
IF NOT resDLL THEN RENVOYER ""
ELSE
// second passage on traite les child : «EnumChildWindows»
// see : https://docs.microsoft.com/fr-fr/windows/win32/api/winuser/nf-winuser-enumchildwindows
resDLL = API(user32_dll, "EnumChildWindows", pHndParent, &EnumWindowsFunction, &Liste)

// Si c'est faux c'est qu'il n'y a pas d'enfant...
IF NOT resDLL THEN RENVOYER ""
END

//-----> la liste contient les handle ( attention --> en format hexadécimal)
Liste = Remplace(Liste, Patern, "") // suppression des pattern (ZZZZZZZZ0x0d) non utilisés
Liste = Liste[[1 A Taille(Liste)-1]] // et suppression du dernier Caract(0x0d) qui ne sert à rien

FOR ALL STRING Temp OF Liste SEPARATED by Caract(0x0d)

MyHandle = Val(Temp,"x") // handle en décimal

IF pHndParent = -1 THEN
xPidParent est un entier système = API(user32_dll, "GetWindowThreadProcessId", MyHandle, &Pid)
END

// On lit le nom de la classe (ne peut pas être vide)
//see : https://docs.microsoft.com/en-us/windows/win32/api/winuser/nf-winuser-getclassnamea
lpClassName = Répète(" ", 512)
nbChar = API(user32_dll, "GetClassNameA", MyHandle, &lpClassName, Taille(lpClassName))
lpClassName = (nbChar > 0 ? lpClassName[[1 sur nbChar]] ELSE "")

// On lit le libellé (il peut être vide)
//see : http://msdn.microsoft.com/en-us/library/windows/desktop/ms633520%28v=vs.85%29.aspx
lpLibellé = Répète(" ", 512)
nbChar = API(user32_dll, "GetWindowTextA", MyHandle, &lpLibellé, Taille(lpLibellé))
lpLibellé = (nbChar > 0 ? lpLibellé[[1 sur nbChar]] ELSE "")

//---> Handle tab ClasseName tab Libellé cr
IF WindowsListe <> "" THEN WindowsListe += CRLF
WindowsListe += NumériqueVersChaîne(MyHandle, "08X") + TAB + SansEspace(lpClassName) + TAB + SansEspace(lpLibellé)
END
RENVOYER WindowsListe